Server : Apache System : Linux server2.corals.io 4.18.0-348.2.1.el8_5.x86_64 #1 SMP Mon Nov 15 09:17:08 EST 2021 x86_64 User : corals ( 1002) PHP Version : 7.4.33 Disable Function : exec,passthru,shell_exec,system Directory :  /opt/rh/gcc-toolset-11/root/usr/share/systemtap/tapset/linux/i386/

Upload File : current_dir [ Writeable ] document_root [ Writeable ]

# set_zone_reclaim ___________________________________________
/*
 * asmlinkage long
 * sys_set_zone_reclaim(unsigned int node,
 *                      unsigned int zone,
 *                      unsigned int state)
 */

@define _SYSCALL_SET_ZONE_RECLAIM_NAME
%(
	name = "set_zone_reclaim"
%)

@define _SYSCALL_SET_ZONE_RECLAIM_ARGSTR
%(
	argstr = sprintf("%d, %d, %d", node, zone, state)
%)

probe syscall.set_zone_reclaim = dw_syscall.set_zone_reclaim !,
                                 nd_syscall.set_zone_reclaim ? {}
probe syscall.set_zone_reclaim.return = dw_syscall.set_zone_reclaim.return !,
                                        nd_syscall.set_zone_reclaim.return ? {}

# dw_set_zone_reclaim _____________________________________________________

probe dw_syscall.set_zone_reclaim = kernel.function("sys_set_zone_reclaim") ?
{
	@_SYSCALL_SET_ZONE_RECLAIM_NAME
	node = $node
	zone = $zone
	state = $state
	@_SYSCALL_SET_ZONE_RECLAIM_ARGSTR
}
probe dw_syscall.set_zone_reclaim.return = kernel.function("sys_set_zone_reclaim").return ?
{
	@_SYSCALL_SET_ZONE_RECLAIM_NAME
	@SYSC_RETVALSTR($return)
}

# nd_set_zone_reclaim _____________________________________________________

probe nd_syscall.set_zone_reclaim = kprobe.function("sys_set_zone_reclaim") ?
{
	@_SYSCALL_SET_ZONE_RECLAIM_NAME
	asmlinkage()
	node = uint_arg(1)
	zone = uint_arg(2)
	state = uint_arg(3)
	@_SYSCALL_SET_ZONE_RECLAIM_ARGSTR
}
probe nd_syscall.set_zone_reclaim.return = kprobe.function("sys_set_zone_reclaim").return ?
{
	@_SYSCALL_SET_ZONE_RECLAIM_NAME
	@SYSC_RETVALSTR(returnval())
}