Server : Apache System : Linux server2.corals.io 4.18.0-348.2.1.el8_5.x86_64 #1 SMP Mon Nov 15 09:17:08 EST 2021 x86_64 User : corals ( 1002) PHP Version : 7.4.33 Disable Function : exec,passthru,shell_exec,system Directory :  /opt/rh/gcc-toolset-11/root/usr/share/systemtap/tapset/linux/

Upload File : current_dir [ Writeable ] document_root [ Writeable ]

# close ______________________________________________________
# long sys_close(unsigned int fd)

@define _SYSCALL_CLOSE_NAME
%(
	name = "close"
%)

@define _SYSCALL_CLOSE_ARGSTR
%(
	argstr = sprint(fd)
%)

@define _SYSCALL_CLOSE_REGARGS
%(
	fd = int_arg(1)
%)

@define _SYSCALL_CLOSE_REGARGS_STORE
%(
        if (@probewrite(fd))
          set_int_arg(1, fd)
%)

probe syscall.close = dw_syscall.close !, nd_syscall.close ? {}
probe syscall.close.return = dw_syscall.close.return !, nd_syscall.close.return ? {}

# dw_close _____________________________________________________

probe dw_syscall.close = kernel.function("sys_close").call
{
	@__syscall_compat_gate(@const("__NR_close"), @const("__NR_compat_close"))
	@_SYSCALL_CLOSE_NAME
	fd = __int32($fd)
	@_SYSCALL_CLOSE_ARGSTR
}
probe dw_syscall.close.return = kernel.function("sys_close").return
{
	@__syscall_compat_gate(@const("__NR_close"), @const("__NR_compat_close"))
	@_SYSCALL_CLOSE_NAME
	@SYSC_RETVALSTR($return)
}

# nd_close _____________________________________________________

probe nd_syscall.close = nd1_syscall.close!, nd2_syscall.close!, tp_syscall.close
  { }

probe nd1_syscall.close = kprobe.function("sys_close") ?
{
	@__syscall_compat_gate(@const("__NR_close"), @const("__NR_compat_close"))
	@_SYSCALL_CLOSE_NAME
	asmlinkage()
	@_SYSCALL_CLOSE_REGARGS
	@_SYSCALL_CLOSE_ARGSTR
}

/* kernel 4.17+ */
probe nd2_syscall.close = kprobe.function(@arch_syscall_prefix "sys_close") ?
{
	__set_syscall_pt_regs(pointer_arg(1))
	@_SYSCALL_CLOSE_NAME
	@_SYSCALL_CLOSE_REGARGS
	@_SYSCALL_CLOSE_ARGSTR
},
{
        %( @_IS_SREG_KERNEL %? @_SYSCALL_CLOSE_REGARGS_STORE %)
}

/* kernel 3.5+, but undesirable because it affects all syscalls */
probe tp_syscall.close = kernel.trace("sys_enter")
{
	__set_syscall_pt_regs($regs)
	@__syscall_compat_gate(@const("__NR_close"), @const("__NR_compat_close"))
	@_SYSCALL_CLOSE_NAME
	@_SYSCALL_CLOSE_REGARGS
	@_SYSCALL_CLOSE_ARGSTR
},
{
        %( @_IS_SREG_KERNEL %? @_SYSCALL_CLOSE_REGARGS_STORE %)
}

probe nd_syscall.close.return = nd1_syscall.close.return!, nd2_syscall.close.return!, tp_syscall.close.return
  { }

probe nd1_syscall.close.return = kprobe.function("sys_close").return ?
{
	@__syscall_compat_gate(@const("__NR_close"), @const("__NR_compat_close"))
	@_SYSCALL_CLOSE_NAME
	@SYSC_RETVALSTR(returnval())
}

/* kernel 4.17+ */
probe nd2_syscall.close.return = kprobe.function(@arch_syscall_prefix "sys_close").return ?
{
	@_SYSCALL_CLOSE_NAME
	@SYSC_RETVALSTR(returnval())
}

/* kernel 3.5+, but undesirable because it affects all syscalls */
probe tp_syscall.close.return = kernel.trace("sys_exit")
{
	__set_syscall_pt_regs($regs)
	@__syscall_compat_gate(@const("__NR_close"), @const("__NR_compat_close"))
	@_SYSCALL_CLOSE_NAME
	@SYSC_RETVALSTR($ret)
}