Server : Apache System : Linux server2.corals.io 4.18.0-348.2.1.el8_5.x86_64 #1 SMP Mon Nov 15 09:17:08 EST 2021 x86_64 User : corals ( 1002) PHP Version : 7.4.33 Disable Function : exec,passthru,shell_exec,system Directory :  /opt/rh/gcc-toolset-11/root/usr/share/systemtap/tapset/linux/

Upload File : current_dir [ Writeable ] document_root [ Writeable ]

# lgetxattr __________________________________________________
# ssize_t sys_lgetxattr(char __user *path,
#               char __user *name,
#               void __user *value,
#               size_t size)
#

@define _SYSCALL_LGETXATTR_NAME
%(
	name = "lgetxattr"
%)

@define _SYSCALL_LGETXATTR_ARGSTR
%(
	argstr = sprintf("%s, %s, %p, %u", path, name_str, value_uaddr, size)
%)

@define _SYSCALL_LGETXATTR_REGARGS
%(
	path = user_string_quoted(pointer_arg(1))
	path_unquoted = user_string_nofault(pointer_arg(1))
# 'name2' should have been 'name_str'.  Deprecate the old name.
%(systemtap_v <= "1.4" %?
	name2 = user_string_quoted(pointer_arg(2))
	name2_unquoted = user_string_nofault(pointer_arg(2))
%)
	name_str = user_string_quoted(pointer_arg(2))
	name_str_unquoted = user_string_nofault(pointer_arg(2))
	value_uaddr = pointer_arg(3)
	size = ulong_arg(4)
%)

@define _SYSCALL_LGETXATTR_REGARGS_STORE
%(
        if (@probewrite(path_unquoted))
          set_user_string_arg(pointer_arg(1), path_unquoted)

%(systemtap_v <= "1.4" %?
	if (@probewrite(name2_unquoted))
	  set_user_string_arg(pointer_arg(2), name2_unquoted)
%)

	if (@probewrite(name_str_unquoted))
	  set_user_string_arg(pointer_arg(2), name_str_unquoted)

	if (@probewrite(value_uaddr))
	  set_pointer_arg(3, value_uaddr)

	if (@probewrite(size))
	  set_ulong_arg(4, size)
%)

probe syscall.lgetxattr = dw_syscall.lgetxattr !, nd_syscall.lgetxattr ? {}
probe syscall.lgetxattr.return = dw_syscall.lgetxattr.return !, nd_syscall.lgetxattr.return ? {}

# dw_lgetxattr _____________________________________________________

probe dw_syscall.lgetxattr = kernel.function("sys_lgetxattr").call
{
	@_SYSCALL_LGETXATTR_NAME
	path = user_string_quoted(@choose_defined($pathname, $path))
# 'name2' should have been 'name_str'.  Deprecate the old name.
%(systemtap_v <= "1.4" %?
	name2 = user_string_quoted($name)
%)
	name_str = user_string_quoted($name)
	value_uaddr = $value
	size = __ulong($size)
	@_SYSCALL_LGETXATTR_ARGSTR
}
probe dw_syscall.lgetxattr.return = kernel.function("sys_lgetxattr").return
{
	@_SYSCALL_LGETXATTR_NAME
	@SYSC_RETVALSTR($return)
}

# nd_lgetxattr _____________________________________________________

probe nd_syscall.lgetxattr = nd1_syscall.lgetxattr!, nd2_syscall.lgetxattr!, tp_syscall.lgetxattr
  { }

probe nd1_syscall.lgetxattr = kprobe.function("sys_lgetxattr") ?
{
	@_SYSCALL_LGETXATTR_NAME
	asmlinkage()
	@_SYSCALL_LGETXATTR_REGARGS
	@_SYSCALL_LGETXATTR_ARGSTR
}

/* kernel 4.17+ */
probe nd2_syscall.lgetxattr = kprobe.function(@arch_syscall_prefix "sys_lgetxattr") ?
{
	__set_syscall_pt_regs(pointer_arg(1))
	@_SYSCALL_LGETXATTR_NAME
	@_SYSCALL_LGETXATTR_REGARGS
	@_SYSCALL_LGETXATTR_ARGSTR
},
{
        %( @_IS_SREG_KERNEL %? @_SYSCALL_LGETXATTR_REGARGS_STORE %)
}

/* kernel 3.5+, but undesirable because it affects all syscalls */
probe tp_syscall.lgetxattr = kernel.trace("sys_enter")
{
	__set_syscall_pt_regs($regs)
	@__syscall_compat_gate(@const("__NR_lgetxattr"), @const("__NR_compat_lgetxattr"))
	@_SYSCALL_LGETXATTR_NAME
	@_SYSCALL_LGETXATTR_REGARGS
	@_SYSCALL_LGETXATTR_ARGSTR
},
{
        %( @_IS_SREG_KERNEL %? @_SYSCALL_LGETXATTR_REGARGS_STORE %)
}

probe nd_syscall.lgetxattr.return = nd1_syscall.lgetxattr.return!, nd2_syscall.lgetxattr.return!, tp_syscall.lgetxattr.return
  { }

probe nd1_syscall.lgetxattr.return = kprobe.function("sys_lgetxattr").return ?
{
	@_SYSCALL_LGETXATTR_NAME
	@SYSC_RETVALSTR(returnval())
}

/* kernel 4.17+ */
probe nd2_syscall.lgetxattr.return = kprobe.function(@arch_syscall_prefix "sys_lgetxattr").return ?
{
	@_SYSCALL_LGETXATTR_NAME
	@SYSC_RETVALSTR(returnval())
}
 
/* kernel 3.5+, but undesirable because it affects all syscalls */
probe tp_syscall.lgetxattr.return = kernel.trace("sys_exit")
{
	__set_syscall_pt_regs($regs)
	@__syscall_compat_gate(@const("__NR_lgetxattr"), @const("__NR_compat_lgetxattr"))
	@_SYSCALL_LGETXATTR_NAME
	@SYSC_RETVALSTR($ret)
}