Server : Apache System : Linux server2.corals.io 4.18.0-348.2.1.el8_5.x86_64 #1 SMP Mon Nov 15 09:17:08 EST 2021 x86_64 User : corals ( 1002) PHP Version : 7.4.33 Disable Function : exec,passthru,shell_exec,system Directory :  /proc/thread-self/root/opt/rh/gcc-toolset-11/root/usr/share/systemtap/examples/io/

Upload File : current_dir [ Writeable ] document_root [ Writeable ]

#!/opt/rh/gcc-toolset-11/root/usr/bin/stap
global reads, writes, totals

probe begin { printf("starting probe\n") }

probe vfs.read.return {
  count = returnval()
  if ( count >= 0 ) {
    reads[execname(),dev] <<< count # statistics array
    totals[execname(),dev] <<< count
  }
}

probe vfs.write.return {
  count = returnval()
  if (count >= 0 ) {
    writes[execname(),dev] <<< count # statistics array
    totals[execname(),dev] <<< count
  }
}

probe end {
  printf("\n%16s %8s %8s %8s %8s %8s %8s %8s\n",
    "", "", "", "read", "read", "", "write", "write")
  printf("%16s %8s %8s %8s %8s %8s %8s %8s\n",
    "name", "device", "read", "KB tot", "B avg", "write", "KB tot", "B avg")
  foreach ([name,dev] in totals @sum- limit 20) { # sort by total io
    printf("%16s %3d, %4d %8d %8d %8d %8d %8d %8d\n",
      name, MAJOR(dev), MINOR(dev),
      @count(reads[name,dev]),
      (@count(reads[name,dev]) ? @sum(reads[name,dev])>>10 : 0 ),
      (@count(reads[name,dev]) ? @avg(reads[name,dev]) : 0 ),
      @count(writes[name,dev]),
      (@count(writes[name,dev]) ? @sum(writes[name,dev])>>10 : 0 ),
      (@count(writes[name,dev]) ? @avg(writes[name,dev]) : 0 ))
  }
}