Server : Apache System : Linux server2.corals.io 4.18.0-348.2.1.el8_5.x86_64 #1 SMP Mon Nov 15 09:17:08 EST 2021 x86_64 User : corals ( 1002) PHP Version : 7.4.33 Disable Function : exec,passthru,shell_exec,system Directory :  /proc/thread-self/root/opt/rh/gcc-toolset-11/root/usr/share/systemtap/examples/profiling/

Upload File : current_dir [ Writeable ] document_root [ Writeable ]

#!/opt/rh/gcc-toolset-11/root/usr/bin/stap

%( CONFIG_64BIT == "y" %?
global profile%[20000], pcount
%:
# On a 32-bit platform, the profile array must be smaller, otherwise
# its allocation will fail on module startup.
global profile%[5000], pcount
%)
probe timer.profile {
  pcount <<< 1
  # NB: we resolve to a function name here (rather than recording only
  # the PC), because during a later pc->name lookup, the process context
  # may be different.
  if (!user_mode())
    try { // modname() can throw
      fn = "k:".modname(addr()).":".symname(addr())
    } catch {
      fn = "k:<unknown>:".symname(addr())
    }
  else {
    try { // umodname() can throw
      fn = "u:".umodname(uaddr()).":".usymname(uaddr())
    } catch {
      fn = "u:<unknown>:".usymname(uaddr())
    }
  }
  profile[fn] <<< 1
}
probe timer.ms(5000) {
  printf ("\n--- %d samples recorded:\n", @count(pcount))
  foreach (f in profile- limit 20) {
    printf ("%-30s\t%6d\n", f, @count(profile[f]))
  }
  delete profile
  delete pcount
}